dim 3,3;
i=e56;
re(z)=(z^i)/i;
im(z)=(z-re(z))/i;
co(z)=re(z)-im(z) i;
Cm(z)=e24 co(z)/e24;
rev(z)=co(z)~;
con(z)=co(z)~';
He(z)=e4 z~'/e4;
Ch(z)=-co(z) e14;
Tr(z)=e2 con(z)/e2;
say
say $wThis external file demonstrates computations in the Minkowski space-time  R^3,1
say $wwith an orthonormal basis  $ge1$w, $ge2$w, $ge3$w, $ge$c4$w  such that  $ge1e1$w = $ge2e2$w = $ge3e3$w = 1
say $wand  $ge$c4$ge$c4$w = -1.  The overall commuting imaginary unit is the bivector  i = $ge$c56$w
say $win the Clifford algebra  Cl_3,3.  The spinor space is the minimal left ideal
say $w(CxCl_3,1)f  where  f  is the primitive idempotent  
f=1/2(1-i e4) 1/2(1-i e12)
f1=f;
f2=e13 f;
f3=e3 f;
f4=e1 f;
say
say $wso that the complex spinor space has a basis  f1=f, f2=e13 f, f3=e3 f, f4=e1 f.
say $wThe real and imaginary parts of  z = x+i y  in  CxCl_3,1 = Cl_3,1+i Cl_3,1
say $ware given by  re(z)  and  im(z).  The complex conjugate  x-i y  (with  x  and
say $wy  in  Cl_3,1) is given by  co(z).  It should be emphasized that  co(z)  does
say $wnot conjugate the entries of the matrix representing  z.  The transpose, the
say $wcomplex conjugate and the Hermitian conjugate of the matrix of  z  are given
say $wby  Tr(z), Cm(z)  and  He(z).
say
say $mPress <CARRIAGE RETURN> or <ENTER>
pause
say                                           $y      [4+3i
say As an example let us consider the spinor  $ypsi =  1+6i
say                                           $y       2-5i
say                                           $y       1-2i]
psi=(4+3i)f1+(1+6i)f2+(2-5i)f3+(1-2i)f4
say
say and compute next its bilinear covariants with the help of the spinor operator
Psi=even(4 re(psi))
pause
say Compute the Dirac current
J=Psi e4 Psi~'
say
say the electromagnetic-moment bivector
S=Psi e12 Psi~'
say
say and the spin vector
K=Psi e3 Psi~'
pause
say Introduce the de Broglie variable
Omega=Psi Psi~'
say
say Compute the energy projection operator
P=Omega-i J
say
say and the spin projection operator
Sigma=1+i e1234 J/K
pause
say Introduce an aggregate of bilinear covariants
Z=4 psi psi~'
say
say and verify that  Z = P Sigma = Sigma P
P Sigma
Sigma P
pause
say Verify that  $wZ = Omega-i J-i S-K e1234
Z-(Omega-i J-i S-K e1234)
say
say $wThis shows that the vector and bivector parts of  Z  are purely imaginary
say
say                                $w         [  25     22-21i    7-26i   2-11i
say Verify that  Z  has the matrix $w Z = 4 *  22+21i     37     28-17i   11-8i
say                                $w          -7-26i  -28-17i    -29     -12+i
say                                $w          -2-11i   -11-8i    -12-i    -5  ]
say
say by computing  $wZij = 4 ((Tr(fi) Z fj)^e1234)/e1234$c, for instance, compute
((Tr(f1) Z f2)^e1234)/e1234
say
say $mCompute some other matrix entries by yourself and then press <ENTER>
pause
say The Dirac current  J  is  a sum of its bilinear covariant components
J
4 (((psi~'*i e1 psi)^e1234)/e1234)/e1
4 (((psi~'*i e2 psi)^e1234)/e1234)/e2
4 (((psi~'*i e3 psi)^e1234)/e1234)/e3
4 (((psi~'*i e4 psi)^e1234)/e1234)/e4
pause
say Verify the Fierz identities
J J
K K
Omega e4 Omega
J.K
J^K-e123 Omega e4 S
pause
say The spinor  psi  can be decomposed into two Weyl spinors.
say
say $wNext, we compute these two Weyl spinors.  $mPress <ENTER>
pause
psiwp=1/2(1+i e1234) psi
psiwn=1/2(1-i e1234) psi
pause
say Compute the bilinear covariants of the two Weyl spinors
Zwp=4 psiwp psiwp~'
Zwn=4 psiwn psiwn~'
say
say and compute the spinor operators for the two Weyl spinors
Psiwp=even(4 re(psiwp))
Psiwn=even(4 re(psiwn))
pause
say Compute the Dirac currents and the spin vectors of the two Weyl spinors
say $w(the electromagnetic-moment bivector and the de Broglie variable vanish
say $wfor a Weyl spinor)
Jwp=Psiwp e4 Psiwp~'
Jwn=Psiwn e4 Psiwn~'
Kwp=Psiwp e3 Psiwp~'
Kwn=Psiwn e3 Psiwn~'
say
say $rObserve positive and negative helicities  Jwp = Kwp  and  Jwn = -Kwn
pause
say Verify the following identity  Z = -i J-K e1234  for the two Weyl spinors
Zwp-(-i Jwp-Kwp e1234)
Zwn-(-i Jwn-Kwn e1234)
pause
say The spinor  psi  can be decomposed into a sum of two Majorana spinors.
say Majorana spinor is an eigen-spinor of the charge conjugation operator. 
say
say $wNext, we compute these two Majorana spinors.  $mPress <ENTER>
pause
psimp=1/2(psi+Ch(psi))
psimn=1/2(psi-Ch(psi))
pause
say Compute the spinor operators of the two Majorana spinors
Psimp=even(4 re(psimp))
Psimn=even(4 re(psimn))
pause
say Compute the Dirac current vectors and the electromagnetic-moment bivectors
say $w(the spin vector and the de Broglie variable vanish for a Majorana spinor)
Jmp=Psimp e4 Psimp~'
Jmn=Psimn e4 Psimn~'
Smp=Psimp e12 Psimp~'
Smn=Psimn e12 Psimn~'
pause
say Observe that for a Majorana spinor the Dirac current  J  is a light-like vector
say which lies in the plane of the electromagnetic-moment bivector  S
Jmp Jmp
Jmn Jmn
Jmp^Smp
Jmn^Smn
pause
say Verify the identity  Z = -i J-i S  for the two Majorana spinors
Zmp=4 psimp psimp~'
Zmn=4 psimn psimn~'
Zmp-(-i Jmp-i Smp)
Zmn-(-i Jmn-i Smn) 
say
say $mEnd of the file SPINOR.
