dim 1,5;
i=e56;
re(z)=(z^i)/i;
im(z)=(z-re(z))/i;
co(z)=re(z)-im(z) i;
Cm(z)=e124 co(z)/e124;
Tr(z)=e24 co(z)~/e24;
He(z)=Cm(Tr(z));
Di(z)=e1 He(z)/e1;
Ch(z)=-i e3 Cm(z);
rev(z)=co(z)~;
con(z)=co(z)~';
say
say $wThis external file demonstrates computations in the Minkowski space-time
say $wR^1,3  with an orthonormal basis  $ge1$w, $ge$c2$w, $ge$c3$w, $ge$c4$w  such that  $ge1e1$w = 1  and
say $ge$c2$ge$c2$w = $ge$c3$ge$c3$w = $ge$c4$ge$c4$w = -1.  The overall commuting imaginary unit is the unit
say $wbivector  i = $ge$c56$w  in the Clifford algebra  Cl_1,5.  The spinor space is
say $wthe minimal left ideal  (CxCl_1,3)f  where  f  is the primitive idempotent  
f=1/2(1+e1) 1/2(1+i e23)
f1=f;
f2=-e24 f;
f3=-e14 f;
f4=-e12 f;
say
say $wso that the spinor space has a basis  f1=f, f2=-e24 f, f3=-e14 f, f4=-e12 f.
say $wThe real and imaginary parts of  z = x+i y  in  CxCl_1,3 = Cl_1,3+i Cl_1,3
say $ware given by  re(z)  and  im(z).  The complex conjugate  x-i y  (with  x
say $wand  y  in  Cl_1,3) is given by  co(z).  It should be emphasized that  co(z)
say $wdoes not conjugate the entries of the matrix representing  z.  The transpose,
say $wthe complex conjugate and the Hermitian conjugate of the matrix of  z  are
say $wgiven by  Tr(z), Cm(z)  and  He(z).
say
say $mPress <CARRIAGE RETURN> or <ENTER>
pause
say                                           $y      [4+3i
say As an example let us consider the spinor  $ypsi =  1+6i
say                                           $y       5+2i
say                                           $y       2+i ]
psi=(4+3i)f1+(1+6i)f2+(5+2i)f3+(2+i)f4
say
say and compute next its bilinear covariants with the help of the spinor operator
Psi=even(4 re(psi))
pause
say Compute the Dirac current
J=Psi e1 Psi~
say
say the electromagnetic moment bivector
S=Psi e23 Psi~
say
say and the spin vector
K=Psi e4 Psi~
pause
say Introduce the de Broglie variable
Omega=Psi Psi~
say
say Compute the energy projection operator
P=Omega+J
say
say and the spin projection operator
Sigma=1-i e1234 J/K
pause
say Introduce an aggregate of bilinear covariants  Z = 4 psi psi~
say and verify that  Z = P Sigma = Sigma P
Z=4 psi psi~
P Sigma
Sigma P
pause
say Verify the Fierz identities
J J
K K
Omega e1 Omega
J.K
J^K+e1 Omega e234 S
say
say $mEnd of the file MINKOWSK.
