say
say You have just read in definitions of exterior functions which permit you
say to evaluate elementary functions in the exterior algebra, for instance:
say
say    $rinvo(x)$g    exterior inverse of  x,  x^invo(x) = 1,  Re(x) =/= 0
say    $rsqrto(x)$g   exterior square root of  x,  sqrto(x)^sqrto(x) = x,  Re(x) > 0
say    $rexpo(x)$g    = 1+x+x^x/2+x^x^x/6+ ...  is a finite series if  Re(x) = 0
say    $rlogo(x)$g    exterior logarithm of  x,  expo(logo(x)) = x,  Re(x) > 0
say    $rasino(x)$g   exterior arcsin of  x,  |Re(x)| < 1
say
invi(x)=1-x+x^x-x^x^x+(x^^4)-(x^^5);
invo(x)=invi((x-Re(x))/Re(x))/Re(x);
sqrti(x)=1+x/2-x^x/8+x^x^x/16-(x^^4)*5/128+(x^^5)*7/256;
sqrto(x)=sqrti((x-Re(x))/Re(x))*sqrt(Re(x));
expi(x)=1+x+x^x/2+x^x^x/6+(x^^4)/24+(x^^5)/120;
expo(x)=expi(x-Re(x))*exp(Re(x));
logi(x)=x-x^x/2+x^x^x/3-(x^^4)/4+(x^^5)/5;
logo(x)=logi((x-Re(x))/Re(x))+log(Re(x));
sini(x)=x-x^x^x/6+(x^^5)/120;
cosi(x)=1-x^x/2+(x^^4)/24;
tani(x)=x+x^x^x/3+(x^^5)*2/15;
sino(x)=sin(Re(x))*cosi(x-Re(x))+cos(Re(x))*sini(x-Re(x));
coso(x)=cos(Re(x))*cosi(x-Re(x))-sin(Re(x))*sini(x-Re(x));
tano(x)=(tan(Re(x))+tani(x-Re(x)))^invo(1-tan(Re(x))*tani(x-Re(x)));
asini(x)=x+x^x^x/6+(x^^5)*3/40;
asino(x)=asin(Re(x))+asini(x*sqrt(1-Re(x)**2)-Re(x)*sqrto(1-x^^2));
acoso(x)=pi/2-asino(x);
atani(x)=x-x^x^x/3+(x^^5)/5;
atano(x)=atan(Re(x))+atani((x-Re(x))^invo(1+Re(x)*x));
sinho(x)=(expo(x)-expo(-x))/2;
cosho(x)=(expo(x)+expo(-x))/2;
tanho(x)=sinho(x)^invo(cosho(x));
asinho(x)=logo(x+sqrto(x^^2+1));
acosho(x)=logo(x+sqrto(x^^2-1));
atanho(x)=1/2*logo((1+x)^invo(1-x));
say As an example, compute
expo(log(2)+pi/2 e12)
logo(ans)
say
say $mEnd of the file EXTERIOR.
