say
say $wThis demonstration file contains examples on the following topics: 
say   -Rotations in three dimensions  R^3
say   -Lorentz transformations of the Minkowski space-time  R^3,1 
say   -Electromagnetism in the Clifford algebras  Cl_3  and  Cl_3,1
say   -Complex Clifford algebra  CxCl_3,1
say   -Cayley algebra of octonions
say   -Conformal transformations and Vahlen matrices
say   -Elementary functions in the exterior algebra
say   -Pure spinors
say   -Conformal covariance of the Maxwell and Dirac equations
say $wIf you need an elementary introduction to CLICAL, type $yTUTOR
say $wTo proceed with this DEMO press ENTER, read, and press $mENTER
pause 
say
say ROTATIONS IN THREE DIMENSIONS  R^3
Cl 3
x=2e1+3e2+5e3
a=(3e1+2e2+e3)/10
s=exp(e123 a/2)
say
say $mPress <GARRIAGE RETURN>
pause
say Rotate the vector  x  about the axis  a  by the angle  |a|
y=s x/s
say
say Check that the length is preserved by computing the squares of the vectors
y y
x x
say
say $mPress <GARRIAGE RETURN>
pause
say LORENTZ TRANSFORMATIONS IN THE MINKOWSKI SPACE-TIME  R^3,1
Cl 3,1
A=4e12+3e13+3e14+e23+e24+2e34
s=exp(A/2)
say
say Lorentz transformation of a space-time point (or event)
x=2e1+3e2+5e3+2e4
y=s x/s'
pause
say Check that the square-norm is preserved
y y
x x
pause
say Lorentz transformation of an electromagnetic bivector  F
F=5e12+e13+2e14+7e23+e24+2e34
G=s F/s
say
say Check that the Lorentz invariants are preserved (j=e1234)
G G/2
F F/2
pause
say Compute the Poynting vector and the energy density
-F e4 F/2
pause
say ELECTROMAGNETISM IN THE CLIFFORD ALGEBRAS  Cl_3  AND  Cl_3,1
say
say $wFirst, begin in the three-dimensional Euclidean space  R^3
E=e1+2e2+4e3
B=3e1+5e2+7e3
say
say The role if the imaginary unit is played by the unit volume element 
i=e123
F=E-iB
pause
say Compute the Lorentz invariants
(E E-B B)/2
E.B
say
say The above computations can be combined in one formula
F F/2
pause
say Compute the energy density and the Poynting vector
(E E+B B)/2
(E^B)/i
say
say The above computations can be combined in one formula
-F'*F/2
pause
say Consider a boost at half the velocity of light
say in the direction of the positive  x-axis
v=0.5e1
a=artanh(v)
s=exp(a/2)
pause
say Lorentz transformation of the electromagnetic field  F
G=s F/s
pause
say Extract out of  G  its magnetic induction
i Pu(2,G)
pause
say Lorentz transformation of a space-time point
x=10+e1+e2
y=s x/s'
pause
say Check that the quadratic form is preserved
y y~'
x x~'
pause
say $mYou could try to study other external files by typing
say
say      $yGET GUIDE
say
say $wor alternatively you could just go on with this Demo-file
say $mby pressing again the <CARRIAGE RETURN>
pause
say $wNext, perform the same computations in the space-time  R^3,1
pause
E=E e4
B=B e4
say
say The role of the imaginary unit is played by the unit volume element
i=e1234
F=E-iB
pause
say Compute the Lorentz invariants
F F/2
pause
say Compute the Poynting vector and the energy density
-F e4 F/2
pause
say
say COMPLEX CLIFFORD ALGEBRA  CxCl_3,1
Cl 3,3
say
say The role of the imaginary unit is played by a unit bivector of  Cl_3,3
i=e56
pause
x=3e1+2e2+e4
y=e3+5e4
say
z=x+i y
pause
A=2e12+2e24+3e34
B=e23+2e31+3e14
say
C=A+i B
pause
say $mThis computation might take a while:
s=exp(C/2)
pause
say Check that taking logarithm returns  C/2
log(s)
pause
say Perform a complex rotation
w=s z/s
pause
say Extract the real and imaginary parts
u=(w^i)/i
v=(w-u)/i
pause
say Check that the invariants of the complex rotation are preserved
x x-y y
u u-v v
say
x.y
u.v
pause
say CAYLEY ALGEBRA OF OCTONIONS
Cl 0,7
say
say Define a Cayley product of two paravectors in  R+R7 (= R+R^0,7)
f=(1-e124)(1-e235)(1-e346)(1-e457)
o(x,y)=Re(x y f)+Pu(1,x y f)
pause
o(e1,2+3e2)
pause
a=1+2e1+4e2+2e3
b=2+e1+2e5
pause
c=o(a,b)
pause
say Check that the absolute value is preserved
abs(c)
abs(a) abs(b)
pause
say Consider the associator of three vectors in  R7
a=3e1+2e4+e5
b=4e2+3e4+e5
c=3e3+e4+2e7
say
say $mThis computation might take a while:
u=o(o(a,b),c)-o(a,o(b,c))
pause
say Show that the associator is perpendicular to the factors
V=a^b^c
(u.V)/V
pause
say Check the Moufang identity  (ab)(ca) = a(bc)a
o(o(a,b),o(c,a))
o(o(a,o(b,c)),a)
pause
say CONFORMAL TRANSFORMATIONS AND VAHLEN MATRICES
say $win the Minkowski space-time  R^3,1
Cl 4,2
say
say $wWe choose the two extra dimensions  $ge4$w, $ge$c6$w  so that our Minkowski space-time
say $whas a basis  $ge1$w, $ge2$w, $ge3$w, $ge$c5$w  where  $ge$c5$ge$c5$w = -1 
epos=e4
eneg=e6
pause
say We give entries of a  2x2-matrix in the Lie algebra of the Vahlen group
A=3+4e12+e23+2e35
B=7e1+e2+3e5
C=5e2+e5
D=-A~
pause
say We give a matrix basis of the Lie algebra of the Vahlen group
mat11=(1+epos^eneg)/2
mat12=(epos-eneg)/2
mat21=(epos+eneg)/2
mat22=(1-epos^eneg)/2
pause
say We form the following $yVAHLEN$c matrix
say in the Lie algebra of the Vahlen group
VAHLEN=A*mat11+B*mat12+C'*mat21+D'*mat22
pause
say By exponentiation we get the $yvahlen$c matrix
vahlen=exp(VAHLEN/2)
pause
Vah11=(vahlen^epos^eneg)/(epos^eneg)
Vah12=((vahlen^eneg)/eneg-Vah11)/epos
Vah21=((vahlen^epos)/epos-Vah11)/eneg
Vah22=(vahlen-Vah11-Vah12*epos-Vah21*eneg)/(epos^eneg)
pause
say Here are the entries ot the $yvahlen$c matrix
a=Vah11+Vah22
b=Vah12-Vah21
c=(Vah12+Vah21)'
d=(Vah11-Vah22)'
pause
say Create a Mobius transformation
g(x)=(a x+b)/(c x+d)
pause
x=6e1+e2+3e3+4e5
y=3e1+4e2+e3+5e5
pause
g(x)
g(y)
pause
say Check the formula  $wg(x)-g(y) = 1/(c x+d)~*(x-y)/(c y+d)
g(x)-g(y)
1/(c x+d)~*(x-y)/(c y+d)
pause
say ELEMENTARY FUNCTIONS IN THE EXTERIOR ALGEBRA
say $wof the Minkowski space-time  R^3,1
say
Cl 3,1
x=3e1+4e2+2e3+3e4
B=pi/2*e12+0.5e34
pause
say Rotate  x  by the angle  pi/2  and perform a boost in the direction  e3
u=exp(B/2)
y=u x/u
pause
y y
x x
pause
say Compare the above ordinary exponential  exp(A) = 1+A+AA/2+AAA/6+...
say to the following exterior exponential  expo(B) = 1+B+B^B/2+B^B^B/6:
expo(B)=1+B+B^B/2+B^B^B/6
v=expo(B)
pause
z=v x/v
z z
x x
pause
say Check that ordinary logarithm and exterior logarithm return  B/2  and  B
log(u)
pause
logi(x)=x-x^x/2+x^x^x/3
logo(x)=log(Re(x))+logi(x/Re(x)-1)
pause
logo(v)
pause
u u~
v v~
pause
say PURE SPINORS
Cl 3,4
v=(e1+e4)(e2+e5)(e3+e6)/8
f=(1+e14)(1+e25)(1+e36)/8
say
say Here  v = e123 f  as the following computation shows:
e123 f
pause
say The following bivectors annul  v:
say $we14-e25, e25-e36
say $we12+e15, e15+e24, e17+e47
say $we13+e16, e16+e34, e27+e57
say $we23+e26, e26+e35, e37+e67
say and their exponential stabilizes  v.
pause
say As an example, take a linear combination of the above bivectors:
B=4(e14-e25)+7(e15+e24)+3(e37+e67)
say
say and exponentiate:       $m ... this computation might take a while ...
s=exp(B/10)
pause
say Check that  s v = v:
s v
v
pause
say Take an arbitrary bivector:
F=4e12+7e25+5e36+3e47+2e56
say
say and exponentiate:        $m ... this computation might take a while ...
u=exp(F/10)
pause
say The product  u*v  is a $wpure spinor
w=u*v
pause
say Check that  w~*Ak*w  vanishes for a pure spinor  w  and a  k-vector  Ak
say when  k = 0,1,2  but not when  k = 3  (v  and  w~*A3*w  are parallel)
A1=2e1+3e2+5e3+7e4+e5+4e6
A2=3e12+4e15+2e23+3e24+5e34+e36+e45
A3=e123+4e126+3e234+2e245+e345+5e356+e456
pause
say $mThese computations might take a while:
w~*w
w~*A1*w
w~*A2*w
pause
w~*A3*w
v
pause
say CONFORMAL COVARIANCE OF THE MAXWELL AND DIRAC EQUATIONS
say $wdemonstrated by the files$y DERIVE4, MAXWELL, DIRAC31, CONFEX31$w:
Cl 3,1
h=1/10000000;
drop 5;
f(x)=x;
Df(x)=1/h*(1/e1(f(x)-f(x-h e1))+1/e2(f(x)-f(x-h e2))+1/e3(f(x)-f(x-h e3))+1/e4(f(x)-f(x-h e4)));
x1(x)=x.(1/e1);
x2(x)=x.(1/e2);
x3(x)=x.(1/e3);
x4(x)=x.(1/e4);
A(x)=(x2(x)**2)e1+x3(x)(x4(x)**2)e2+(x1(x)**2+(x2(x)**2)(x4(x)**2))e3+x1(x)x2(x)(x3(x)**2)e4;
F(x)=2x2(x)e12-2x1(x)e13-x2(x)(x3(x)**2)e14+(1-2x2(x))(x4(x)**2)e23-x3(x)(x1(x)x3(x)+2x4(x))e24-2x2(x)(x1(x)x3(x)+x2(x)x4(x))e34;
J(x)=-2e1+2x3(x)e2+2(-1-x4(x)**2+x2(x)**2)e3-2x1(x)x2(x)e4;
x=e1+0.5e2+e3+1.25e4;
say
say The Maxwell equations $wDF(x) = J(x)$c:
f(x)=F(x)
Df(x)
J(x)
pause
say Conformal covariance of the Maxwell equations:
a=1.173676808+0.233952456e12-0.001888389e13+0.012881859e14-0.000406802e23+0.006792092e24+0.289055079e34+0.057624664e1234;
b=0.359916271e1+0.099165456e2-0.002473828e3+0.197111126e4-0.000458312e123+0.040285180e124+0.088350788e134+0.024368630e234;
c=0.051819808e1+0.000639166e2+0.001236914e3+0.099580742e4+0.000229625e123+0.020142590e124+0.012588472e134+0.000115742e234;
d=0.869042918+0.177411202e12-0.001886780e13-0.012296043e14-0.000407070e23-0.003277191e24+0.214446961e34+0.043777027e1234;
g(x)=Pu(1,(a x+b)/(c x+d));
Mg(x)=1/Re((c x+d)(c x+d)~);
f(x)=1/(c x+d)F(g(x))(c x+d)(Mg(x)**2)
Df(x)
1/(c x+d)J(g(x))(c x+d)(Mg(x)**3)
pause
r(x)=sqrt((x^e4)**2);
expv(x)=(x.e1+e12(x.e2))/sqrt((x^e34)**2);
cost(x)=(x.e3)/r(x);
sint(x)=sqrt((x^e34)**2)/r(x);
A(x)=e4/r(x);
F(x)=(x^e4)/(r(x)**3);
za=-0.4;
e=za;
ms=0.7;
m=ms;
p1(x)=sqrt(1+1/sqrt(1+za za/(4-za za))) cost(x);
p2(x)=-sqrt(1+1/sqrt(1+za za/(4-za za))) 1/2sint(x)expv(x);
p3(x)=e12 sqrt(1-1/sqrt(1+za za/(4-za za))) (3/2(cost(x)**2)-1/2);
p4(x)=e12 sqrt(1-1/sqrt(1+za za/(4-za za))) 3/2sint(x)cost(x)expv(x);
pp(x)=p1(x)+e13 p2(x)-e34 p3(x)-e14 p4(x);
gp(x)=exp(za ms/2 r(x))exp(log(r(x))(sqrt(4-za za)-1));
k0(x)=exp(e12 ms/2 sqrt(4-za za) (x.e4));
p(x)=pp(x) gp(x) k0(x);
say The Dirac-Hestenes equation $wDp(x)e21-e A(x)p(x) = m p(x)e4$c:
f(x)=p(x)
Df(x)e21
e A(x)p(x)+m p(x)e4
pause
say Conformal covariance of the Dirac-Hestenes equation:
f(x)=1/(c x+d)p(g(x))Mg(x)
Df(x)e21
e 1/(c x+d)A(g(x))(c x+d)Mg(x)f(x)+m Mg(x)f(x)e4
pause
say $gYou have completed the demonstration file DEMO.
say More information about CLICAL can be found by writing:
say
say    $yGET GUIDE
say
say $mEnd of the external file DEMO.
